Add midpoint for matrices and polynomials

Author: d-torrance

M2/Macaulay2/m2/intervals.m2

@@ -123,6 +123,16 @@ isEmpty CCi := x -> isEmptyRRi realPart x or isEmptyRRi imaginaryPart x
 midpoint = method()
 midpoint Number := identity
 midpoint RRi := midpoint CCi := midpoint0
+midpoint RingElement := f -> (
+    R := ring f;
+    kk := coefficientRing R;
+    S := R.cache#"midpoint ring" ??= (
+	if instance(kk, RealIntervalField)
+	then RR_(precision kk) monoid R
+	else if instance(kk, ComplexIntervalField)
+	then CC_(precision kk) monoid R
+	else R);
+    sum(listForm f, (m, c) -> midpoint c * product(#m, i -> S_i^(m#i))))
 
 toExternalString RRi := x -> "interval" | toExternalString (left x, right x)
 toExternalString CCi := x -> "interval" | toExternalString (left realPart x+(left imaginaryPart x)*ii,right realPart x+(right imaginaryPart x)*ii)

M2/Macaulay2/m2/matrix.m2

@@ -781,6 +781,8 @@ leadComponent = method()
 leadComponent Matrix := List => m -> nonnull for c to numColumns m - 1 list position(numRows m, r -> m_(r,c) != 0, Reverse => true)
 leadComponent Vector := ZZ   => v -> try first leadComponent matrix v else null
 
+midpoint Matrix := f -> matrix apply(entries f, row -> midpoint \ row)
+
 -- Local Variables:
 -- compile-command: "make -C $M2BUILDDIR/Macaulay2/m2 "
 -- End:

M2/Macaulay2/packages/Macaulay2Doc/doc_intervals.m2

@@ -46,8 +46,10 @@ doc ///
 Key
      midpoint
     (midpoint, CCi)
+    (midpoint, Matrix)
     (midpoint, Number)
     (midpoint, RRi)
+    (midpoint, RingElement)
 Headline
     midpoint of an interval
 Usage
@@ -68,6 +70,19 @@ Description
   Example
     interval(2 + 3*ii, 4 + 7*ii)
     midpoint oo
+  Text
+    The midpoint of a matrix is the matrix containing the midpoints of
+    its entries.
+  Example
+    A = matrix{{interval(1,3), interval(3,5)}, {interval(5,7), interval(7,9)}}
+    midpoint A
+  Text
+    The midpoint of a polynomial is obtained by taking the midpoints of the
+    coefficients.
+  Example
+    R = RRi[x,y,z]
+    f = interval(1,3)*x + interval(3,5)*y + interval(5,7)*z
+    midpoint f
 SeeAlso
     left
     right

M2/Macaulay2/tests/normal/RRi.m2

@@ -119,6 +119,14 @@ assert isSubset(K^2,K*K)
 assert not isSubset(K*K,K^2)
 assert isSubset(toCCi(interval(-14,17),interval(-10,24)),L*K)
 
+A = matrix{{interval(1,3), interval(3,5)}, {interval(5,7), interval(7,9)}}
+assert(midpoint A == matrix(RR, {{2, 4}, {6, 8}}))
+
+R = RRi[x,y,z]
+f = interval(1,3)*x + interval(3,5)*y + interval(5,7)*z
+use ring midpoint f
+assert(midpoint f == 2*x + 4*y + 6*z)
+
 --- TO FIX: ---------------------------------------------
 
 -*