Remove need to have --watchos_cpus defined when building iOS applications with watchOS apps (#2838)

Author: adincebic

apple/internal/transition_support.bzl

@@ -60,6 +60,18 @@ _CPU_TO_DEFAULT_PLATFORM_FLAG = {
     for cpu, platform_name in CPU_TO_DEFAULT_PLATFORM_NAME.items()
 }
 
+_IOS_ARCH_TO_EARLIEST_WATCHOS = {
+    "x86_64": "x86_64",
+    "sim_arm64": "arm64",
+    "arm64": "armv7k",
+}
+
+_IOS_ARCH_TO_64_BIT_WATCHOS = {
+    "x86_64": "x86_64",
+    "sim_arm64": "arm64",
+    "arm64": "arm64_32",
+}
+
 def _platform_specific_cpu_setting_name(platform_type):
     """Returns the name of a platform-specific CPU setting.
 
@@ -77,12 +89,63 @@ def _platform_specific_cpu_setting_name(platform_type):
         fail("ERROR: Unknown platform type: {}".format(platform_type))
     return flag
 
-def _environment_archs(platform_type, settings):
+def _environment_arch_from_cpu(*, cpu_value, platform_prefix):
+    """Returns a specific platform's environment arch if found from the `--cpu` command line option.
+
+    Args:
+        cpu_value: String found from an incoming `--cpu` value.
+        platform_prefix: The platform prefix to search for within the incoming `--cpu` string.
+
+    Returns:
+        The value following the platform_prefix if it was found in the incoming `--cpu` value, which
+            is expected to be a valid environment arch, or `None`.
+    """
+    if cpu_value.startswith(platform_prefix):
+        return cpu_value[len(platform_prefix):]
+    return None
+
+def _watchos_environment_archs_from_ios(*, cpu_value, minimum_os_version, settings):
+    """Returns a set of watchOS environment archs based on incoming iOS archs.
+
+    Args:
+        cpu_value: String found from an incoming `--cpu` value.
+        minimum_os_version: A string coming directly from a rule's `minimum_os_version` attribute.
+        settings: A dictionary whose set of keys is defined by the inputs parameter, typically from
+            the settings argument found on the implementation function of the current Starlark
+            transition.
+
+    Returns:
+        A list of watchOS environment archs if any were found from the iOS environment archs, or an
+            empty list if none were found.
+    """
+    environment_archs = []
+    ios_archs = settings[_platform_specific_cpu_setting_name("ios")]
+    if not ios_archs:
+        ios_arch = _environment_arch_from_cpu(
+            cpu_value = cpu_value,
+            platform_prefix = "ios_",
+        )
+        if ios_arch:
+            ios_archs = [ios_arch]
+    if ios_archs:
+        # Make sure to return a fallback compatible with the rule's assigned minimum OS.
+        ios_to_watchos_arch_dict = _IOS_ARCH_TO_64_BIT_WATCHOS
+        if apple_common.dotted_version(minimum_os_version) < apple_common.dotted_version("9.0"):
+            ios_to_watchos_arch_dict = _IOS_ARCH_TO_EARLIEST_WATCHOS
+        environment_archs = [
+            ios_to_watchos_arch_dict[arch]
+            for arch in ios_archs
+            if ios_to_watchos_arch_dict.get(arch)
+        ]
+    return environment_archs
+
+def _environment_archs(platform_type, minimum_os_version, settings):
     """Returns a full set of environment archs from the incoming command line options.
 
     Args:
         platform_type: A string denoting the platform type; `"ios"`, `"macos"`,
             `"tvos"`, `"visionos"`, or `"watchos"`.
+        minimum_os_version: A string coming directly from a rule's `minimum_os_version` attribute.
         settings: A dictionary whose set of keys is defined by the inputs parameter, typically from
             the settings argument found on the implementation function of the current Starlark
             transition.
@@ -93,11 +156,30 @@ def _environment_archs(platform_type, settings):
     """
     environment_archs = settings[_platform_specific_cpu_setting_name(platform_type)]
     if not environment_archs:
+        cpu_value = settings["//command_line_option:cpu"]
         if platform_type == "ios":
-            # Legacy exception to interpret the --cpu as an iOS arch.
-            cpu_value = settings["//command_line_option:cpu"]
-            if cpu_value.startswith("ios_"):
-                environment_archs = [cpu_value[4:]]
+            # Legacy handling to interpret the --cpu as an iOS environment arch.
+            ios_arch = _environment_arch_from_cpu(
+                cpu_value = cpu_value,
+                platform_prefix = "ios_",
+            )
+            if ios_arch:
+                environment_archs = [ios_arch]
+        if platform_type == "watchos":
+            # Interpret the --cpu as a watchOS environment arch; often will be set by a transition.
+            watchos_arch = _environment_arch_from_cpu(
+                cpu_value = cpu_value,
+                platform_prefix = "watchos_",
+            )
+            if watchos_arch:
+                environment_archs = [watchos_arch]
+            else:
+                # If not found, generate watchOS archs via incoming iOS environment arch(s).
+                environment_archs = _watchos_environment_archs_from_ios(
+                    cpu_value = cpu_value,
+                    minimum_os_version = minimum_os_version,
+                    settings = settings,
+                )
         if not environment_archs:
             environment_archs = [
                 _cpu_string(
@@ -366,10 +448,11 @@ def _command_line_options_for_xcframework_platform(
 
 def _apple_rule_base_transition_impl(settings, attr):
     """Rule transition for Apple rules using Bazel CPUs and a valid Apple split transition."""
+    minimum_os_version = attr.minimum_os_version
     platform_type = attr.platform_type
     return _command_line_options(
-        environment_arch = _environment_archs(platform_type, settings)[0],
-        minimum_os_version = attr.minimum_os_version,
+        environment_arch = _environment_archs(platform_type, minimum_os_version, settings)[0],
+        minimum_os_version = minimum_os_version,
         platform_type = platform_type,
         settings = settings,
     )
@@ -425,13 +508,13 @@ _apple_rule_base_transition = transition(
 )
 
 def _apple_platforms_rule_base_transition_impl(settings, attr):
-    """Rule transition for Apple rules using Bazel platforms."""
+    """Rule transition for Apple rules using Bazel platforms and the Starlark split transition."""
     minimum_os_version = attr.minimum_os_version
     platform_type = attr.platform_type
     environment_arch = None
     if not settings["//command_line_option:incompatible_enable_apple_toolchain_resolution"]:
         # Add fallback to match an anticipated split of Apple cpu-based resolution
-        environment_arch = _environment_archs(platform_type, settings)[0]
+        environment_arch = _environment_archs(platform_type, minimum_os_version, settings)[0]
     return _command_line_options(
         apple_platforms = settings["//command_line_option:apple_platforms"],
         environment_arch = environment_arch,
@@ -453,10 +536,14 @@ def _apple_platforms_rule_bundle_output_base_transition_impl(settings, attr):
     environment_arch = None
     if not settings["//command_line_option:incompatible_enable_apple_toolchain_resolution"]:
         # Add fallback to match an anticipated split of Apple cpu-based resolution
-        environment_arch = _environment_archs(platform_type, settings)[0]
+        environment_arch = _environment_archs(
+            platform_type = platform_type,
+            settings = settings,
+            minimum_os_version = minimum_os_version,
+        )
     return _command_line_options(
         apple_platforms = settings["//command_line_option:apple_platforms"],
-        environment_arch = environment_arch,
+        environment_arch = environment_arch[0],
         force_bundle_outputs = True,
         minimum_os_version = minimum_os_version,
         platform_type = platform_type,
@@ -558,8 +645,9 @@ def _apple_platform_split_transition_impl(settings, attr):
                 )
 
     else:
+        minimum_os_version = attr.minimum_os_version
         platform_type = attr.platform_type
-        for environment_arch in _environment_archs(platform_type, settings):
+        for environment_arch in _environment_archs(platform_type, minimum_os_version, settings):
             found_cpu = _cpu_string(
                 environment_arch = environment_arch,
                 platform_type = platform_type,
@@ -568,7 +656,6 @@ def _apple_platform_split_transition_impl(settings, attr):
             if found_cpu in output_dictionary:
                 continue
 
-            minimum_os_version = attr.minimum_os_version
             environment_arch_is_supported = _is_arch_supported_for_target_tuple(
                 environment_arch = environment_arch,
                 minimum_os_version = minimum_os_version,

test/starlark_tests/targets_under_test/watchos/BUILD

@@ -227,13 +227,15 @@ watchos_application(
     name = "app_arm64_support",
     app_icons = ["//test/starlark_tests/resources:WatchAppIcon.xcassets"],
     bundle_id = "com.google.example",
-    extension = ":ext_arm64_support",
     infoplists = [
         "//test/starlark_tests/resources:WatchosAppInfo.plist",
     ],
     minimum_os_version = common.min_os_watchos.arm64_support,
     provisioning_profile = "//test/testdata/provisioning:integration_testing_ios.mobileprovision",
     tags = common.fixture_tags,
+    deps = [
+        "//test/starlark_tests/resources:watchkit_single_target_app_main_lib",
+    ],
 )
 
 watchos_extension(
@@ -257,6 +259,21 @@ watchos_extension(
     ],
 )
 
+watchos_extension(
+    name = "ext_arm64_support",
+    bundle_id = "com.google.example.ext",
+    entitlements = "//test/starlark_tests/resources:entitlements.plist",
+    infoplists = [
+        "//test/starlark_tests/resources:WatchosExtensionInfo.plist",
+    ],
+    minimum_os_version = common.min_os_watchos.arm64_support,
+    provisioning_profile = "//test/testdata/provisioning:integration_testing_ios.mobileprovision",
+    tags = common.fixture_tags,
+    deps = [
+        "//test/starlark_tests/resources:watchkit_ext_main_lib",
+    ],
+)
+
 watchos_extension(
     name = "ext_with_fmwk",
     bundle_id = "com.google.example.ext",
@@ -369,27 +386,28 @@ watchos_extension(
     tags = common.fixture_tags,
 )
 
-watchos_extension(
-    name = "ext_arm64_support",
-    bundle_id = "com.google.example.ext",
+ios_application(
+    name = "app_companion",
+    bundle_id = "com.google",
+    families = ["iphone"],
     infoplists = [
-        "//test/starlark_tests/resources:WatchosExtensionInfo.plist",
+        "//test/starlark_tests/resources:Info.plist",
     ],
-    minimum_os_version = common.min_os_watchos.arm64_support,
+    minimum_os_version = common.min_os_ios.baseline,
     provisioning_profile = "//test/testdata/provisioning:integration_testing_ios.mobileprovision",
-    resources = [
-        "//test/starlark_tests/resources:example_filegroup",
-        "//test/starlark_tests/resources:localization",
-        "//test/starlark_tests/resources:resource_bundle",
-    ],
     tags = common.fixture_tags,
+    visibility = [
+        "//test/starlark_tests:__subpackages__",
+        "//tools/dossier_codesigningtool:__pkg__",
+    ],
+    watch_application = ":app",
     deps = [
-        "//test/starlark_tests/resources:watchkit_ext_main_lib",
+        "//test/starlark_tests/resources:objc_main_lib",
     ],
 )
 
 ios_application(
-    name = "app_companion",
+    name = "app_companion_arm64_support",
     bundle_id = "com.google",
     families = ["iphone"],
     infoplists = [
@@ -402,7 +420,7 @@ ios_application(
         "//test/starlark_tests:__subpackages__",
         "//tools/dossier_codesigningtool:__pkg__",
     ],
-    watch_application = ":app",
+    watch_application = ":app_arm64_support",
     deps = [
         "//test/starlark_tests/resources:objc_main_lib",
     ],

test/starlark_tests/watchos_application_tests.bzl

@@ -115,6 +115,60 @@ def watchos_application_test_suite(name):
         tags = [name],
     )
 
+    # Test that the output stub binary is identified as watchOS simulator via the Mach-O load
+    # command LC_VERSION_MIN_WATCHOS for the arm64 binary slice when only iOS cpus are defined, and
+    # that 32-bit archs are eliminated.
+    binary_contents_test(
+        name = "{}_simulator_ios_cpus_intel_platform_test".format(name),
+        build_type = "simulator",
+        target_under_test = "//test/starlark_tests/targets_under_test/watchos:app_companion",
+        cpus = {
+            "ios_multi_cpus": ["x86_64", "sim_arm64"],
+            "watchos_cpus": [""],
+        },
+        binary_test_file = "$BUNDLE_ROOT/Watch/app.app/_WatchKitStub/WK",
+        binary_test_architecture = "x86_64",
+        binary_not_contains_architectures = ["i386", "arm64e"],
+        macho_load_commands_contain = ["cmd LC_VERSION_MIN_WATCHOS"],
+        tags = [name],
+    )
+
+    # Test that the output application binary is identified as watchOS simulator via the Mach-O
+    # load command LC_BUILD_VERSION for the arm64 binary slice when only iOS cpus are defined, and
+    # that 32-bit archs are eliminated.
+    binary_contents_test(
+        name = "{}_simulator_ios_cpus_arm_platform_test".format(name),
+        build_type = "simulator",
+        target_under_test = "//test/starlark_tests/targets_under_test/watchos:app_companion",
+        cpus = {
+            "ios_multi_cpus": ["x86_64", "sim_arm64"],
+            "watchos_cpus": [""],
+        },
+        binary_test_file = "$BUNDLE_ROOT/Watch/app.app/_WatchKitStub/WK",
+        binary_test_architecture = "arm64",
+        binary_not_contains_architectures = ["i386", "arm64e"],
+        macho_load_commands_contain = ["cmd LC_BUILD_VERSION", "platform WATCHOSSIMULATOR"],
+        tags = [name],
+    )
+
+    # Test that the output stub binary is identified as watchOS simulator via the Mach-O load
+    # command LC_VERSION_MIN_WATCHOS for the arm64 binary slice when only iOS cpus are defined, and
+    # that it defaults to armv7k.
+    binary_contents_test(
+        name = "{}_device_ios_cpus_platform_test".format(name),
+        build_type = "device",
+        target_under_test = "//test/starlark_tests/targets_under_test/watchos:app_companion",
+        cpus = {
+            "ios_multi_cpus": ["arm64"],
+            "watchos_cpus": [""],
+        },
+        binary_test_file = "$BUNDLE_ROOT/Watch/app.app/app",
+        binary_test_architecture = "armv7k",
+        binary_not_contains_architectures = ["arm64_32", "arm64", "arm64e"],
+        macho_load_commands_contain = ["cmd LC_VERSION_MIN_WATCHOS"],
+        tags = [name],
+    )
+
     # Test that the output multi-arch stub binary is identified as watchOS simulator via the Mach-O
     # load command LC_BUILD_VERSION for the arm64 binary slice, and that 32-bit archs are
     # eliminated.