Fix bug in CirculantGraph (Issue #764)

Author: wilfwilson

doc/examples.xml

@@ -1044,19 +1044,29 @@ true]]></Example>
     <A>par</A> is <C>[1,<A>n</A>]</C> then the graph is the <A>n</A>th Mobius
     ladder graph.<P/>
 
-    A circulant graph is biconnected, cyclic, Hamiltonian, regular, and vertex
-    transitive.<P/>
+    A circulant graph is vertex transitive, but is not necessarily connected
+    (consider <C>CirculantGraph(4, [2])</C>, for example).  However, a
+    <E>connected</E> circulant graph is also Hamiltonian and biconnected.<P/>
 
     See <URL>https://mathworld.wolfram.com/CirculantGraph.html</URL> for further
     details.<P/>
 
     &STANDARD_FILT_TEXT;
 
 <Example><![CDATA[
-gap> D := CirculantGraph(6, [1, 2, 3]);
+gap> D := CirculantGraph(6, [2]);
+<immutable vertex-transitive symmetric digraph with 6 vertices, 12 edg\
+es>
+gap> DigraphNrConnectedComponents(D);
+2
+gap> D := CirculantGraph(6, [2, 3]);
 <immutable Hamiltonian biconnected vertex-transitive symmetric digraph\
- with 6 vertices, 30 edges>
-gap> IsIsomorphicDigraph(D, CompleteDigraph(6));
+ with 6 vertices, 18 edges>
+gap> AutomorphismGroup(D) = DihedralGroup(IsPermGroup, 12);
+true
+gap> HamiltonianPath(D);
+[ 1, 3, 5, 2, 6, 4 ]
+gap> IsCompleteDigraph(CirculantGraph(6, [1, 2, 3]));
 true]]></Example>
   </Description>
 </ManSection>

gap/examples.gi

@@ -1103,8 +1103,7 @@ function(_, n, par)
     ErrorNoReturn("arguments must be an integer <n> greater ",
                   "than 1 and a list of integers between 1 and n,");
   fi;
-  D := Digraph(IsMutableDigraph, []);
-  DigraphAddVertices(D, n);
+  D := EmptyDigraph(IsMutableDigraph, n);
   for i in [1 .. n] do
     for j in par do
       if (i - j) mod n = 0 then
@@ -1130,11 +1129,14 @@ function(_, n, par)
   D := MakeImmutable(CirculantGraphCons(IsMutableDigraph, n, par));
   SetIsMultiDigraph(D, false);
   SetIsSymmetricDigraph(D, true);
-  SetIsUndirectedTree(D, false);
-  SetIsRegularDigraph(D, true);
   SetIsVertexTransitive(D, true);
-  SetIsHamiltonianDigraph(D, true);
-  SetIsBiconnectedDigraph(D, true);
+  SetIsUndirectedTree(D, false);
+  SetIsUndirectedForest(D, IsEmpty(par) or
+                           (IsEvenInt(n) and Unique(par) = [n / 2]));
+  if Gcd(Concatenation([n], par)) = 1 then
+    SetIsHamiltonianDigraph(D, true);
+    SetIsBiconnectedDigraph(D, true);
+  fi;
   return D;
 end);
 

tst/standard/examples.tst

@@ -546,6 +546,18 @@ gap> D := CirculantGraph(10, [1, 5]);
  vertices, 30 edges>
 gap> IsIsomorphicDigraph(D, MobiusLadderGraph(5));
 true
+gap> Set(Filtered(Combinations([1 .. 6]),
+> x -> IsUndirectedForest(DigraphCopy(CirculantGraph(6, x)))));
+[ [  ], [ 3 ] ]
+gap> Set(Filtered(Combinations([1 .. 6]),
+> x -> IsUndirectedForest(CirculantGraph(6, x))));
+[ [  ], [ 3 ] ]
+gap> D := CirculantGraph(6, [3]);
+<immutable undirected forest with 6 vertices>
+gap> IsUndirectedForest(D);
+true
+gap> IsUndirectedForest(DigraphCopy(D));
+true
 
 # CycleGraph
 gap> IsIsomorphicDigraph(CycleGraph(5), DigraphSymmetricClosure(CycleDigraph(5)));

tst/testinstall.tst

@@ -472,6 +472,29 @@ gap> d := Digraph([[2, 3, 4, 5], [1, 3, 4], [1, 2, 4, 5], [1, 2, 3, 5],
 gap> Length(SubdigraphsMonomorphisms(CompleteMultipartiteDigraph([2, 3]), d));
 4
 
+# Issue #764 Disconnected CirculantGraphs are not Hamiltonian, etc
+gap> D := CirculantGraph(12, [2, 4]);
+<immutable vertex-transitive symmetric digraph with 12 vertices, 48 edges>
+gap> IsHamiltonianDigraph(D) or IsBiconnectedDigraph(D);
+false
+gap> D := DigraphCopy(D);;
+gap> IsHamiltonianDigraph(D) or IsBiconnectedDigraph(D);
+false
+gap> IsVertexTransitive(D);
+true
+gap> D := CirculantGraph(4, [2]);
+<immutable undirected forest with 4 vertices>
+gap> IsHamiltonianDigraph(D) or IsBiconnectedDigraph(D);
+false
+gap> D := CirculantGraph(6, [2]);
+<immutable vertex-transitive symmetric digraph with 6 vertices, 12 edges>
+gap> IsHamiltonianDigraph(D) or IsBiconnectedDigraph(D);
+false
+gap> D := DigraphCopy(CirculantGraph(9, [3]));
+<immutable digraph with 9 vertices, 18 edges>
+gap> IsHamiltonianDigraph(D) or IsBiconnectedDigraph(D);
+false
+
 # Issue #818 IsConnectedDigraph for a digraph without vertices
 gap> D := Digraph([]);;
 gap> IsConnectedDigraph(D);