|
| 1 | +# Copyright (c) 2014: SCS.jl contributors |
| 2 | +# |
| 3 | +# Use of this source code is governed by an MIT-style license that can be found |
| 4 | +# in the LICENSE.md file or at https://opensource.org/licenses/MIT. |
| 5 | + |
| 6 | +""" |
| 7 | + struct ComplexPositiveSemidefiniteConeTriangle <: MOI.AbstractVectorSet |
| 8 | + side_dimension::Int |
| 9 | + end |
| 10 | +
|
| 11 | +Similar to `HermitianPositiveSemidefiniteConeTriangle` but its |
| 12 | +vectorization interleaves real and imaginary parts of the off-diagonal. |
| 13 | +""" |
| 14 | +struct ComplexPositiveSemidefiniteConeTriangle <: MOI.AbstractVectorSet |
| 15 | + side_dimension::Int |
| 16 | +end |
| 17 | + |
| 18 | +function MOI.Utilities.set_with_dimension( |
| 19 | + ::Type{ComplexPositiveSemidefiniteConeTriangle}, |
| 20 | + dim, |
| 21 | +) |
| 22 | + return ComplexPositiveSemidefiniteConeTriangle(isqrt(dim)) |
| 23 | +end |
| 24 | + |
| 25 | +function Base.copy(x::ComplexPositiveSemidefiniteConeTriangle) |
| 26 | + return ComplexPositiveSemidefiniteConeTriangle(x.side_dimension) |
| 27 | +end |
| 28 | + |
| 29 | +function MOI.side_dimension(x::ComplexPositiveSemidefiniteConeTriangle) |
| 30 | + return x.side_dimension |
| 31 | +end |
| 32 | + |
| 33 | +function MOI.dimension(x::ComplexPositiveSemidefiniteConeTriangle) |
| 34 | + return x.side_dimension^2 |
| 35 | +end |
| 36 | + |
| 37 | +import MutableArithmetics as MA |
| 38 | + |
| 39 | +function MOI.Utilities.set_dot( |
| 40 | + x::AbstractVector{S}, |
| 41 | + y::AbstractVector{T}, |
| 42 | + set::ComplexPositiveSemidefiniteConeTriangle, |
| 43 | +) where {S,T} |
| 44 | + U = MA.promote_operation(MA.add_mul, S, T) |
| 45 | + result = zero(U) |
| 46 | + d = set.side_dimension |
| 47 | + k = 0 |
| 48 | + for j in 1:d |
| 49 | + for i in 1:j-1 |
| 50 | + k += 1 |
| 51 | + result = MA.add_mul!!(result, 2, x[k], y[k]) |
| 52 | + k += 1 |
| 53 | + result = MA.add_mul!!(result, 2, x[k], y[k]) |
| 54 | + end |
| 55 | + k += 1 |
| 56 | + result = MA.add_mul!!(result, x[k], y[k]) |
| 57 | + end |
| 58 | + return result |
| 59 | +end |
| 60 | + |
| 61 | +function MOI.Utilities.dot_coefficients( |
| 62 | + a::AbstractVector, |
| 63 | + set::ComplexPositiveSemidefiniteConeTriangle, |
| 64 | +) |
| 65 | + d = set.side_dimension |
| 66 | + b = copy(a) |
| 67 | + k = 0 |
| 68 | + for j in 1:d |
| 69 | + for i in 1:j-1 |
| 70 | + k += 1 |
| 71 | + b[k] /= 2 |
| 72 | + k += 1 |
| 73 | + b[k] /= 2 |
| 74 | + end |
| 75 | + k += 1 |
| 76 | + end |
| 77 | + return b |
| 78 | +end |
| 79 | + |
| 80 | +function MOI.is_set_dot_scaled(::Type{ComplexPositiveSemidefiniteConeTriangle}) |
| 81 | + return true |
| 82 | +end |
| 83 | + |
| 84 | +struct HermitianComplexPSDConeBridge{T,F} <: |
| 85 | + MOI.Bridges.Constraint.SetMapBridge{ |
| 86 | + T, |
| 87 | + ComplexPositiveSemidefiniteConeTriangle, |
| 88 | + MOI.HermitianPositiveSemidefiniteConeTriangle, |
| 89 | + F, |
| 90 | + F, |
| 91 | +} |
| 92 | + constraint::MOI.ConstraintIndex{F,ComplexPositiveSemidefiniteConeTriangle} |
| 93 | +end |
| 94 | + |
| 95 | +MOI.Bridges.bridging_cost(::Type{<:HermitianComplexPSDConeBridge}) = 0.1 |
| 96 | + |
| 97 | +function MOI.Bridges.Constraint.concrete_bridge_type( |
| 98 | + ::Type{HermitianComplexPSDConeBridge{T}}, |
| 99 | + ::Type{F}, |
| 100 | + ::Type{MOI.HermitianPositiveSemidefiniteConeTriangle}, |
| 101 | +) where {T,F<:MOI.AbstractVectorFunction} |
| 102 | + return HermitianComplexPSDConeBridge{T,F} |
| 103 | +end |
| 104 | + |
| 105 | +function MOI.Bridges.map_set( |
| 106 | + ::Type{<:HermitianComplexPSDConeBridge}, |
| 107 | + set::MOI.HermitianPositiveSemidefiniteConeTriangle, |
| 108 | +) |
| 109 | + return ComplexPositiveSemidefiniteConeTriangle(MOI.side_dimension(set)) |
| 110 | +end |
| 111 | + |
| 112 | +function MOI.Bridges.inverse_map_set( |
| 113 | + ::Type{<:HermitianComplexPSDConeBridge}, |
| 114 | + set::ComplexPositiveSemidefiniteConeTriangle, |
| 115 | +) |
| 116 | + return MOI.HermitianPositiveSemidefiniteConeTriangle(set.side_dimension) |
| 117 | +end |
| 118 | + |
| 119 | +function _hermitian_to_complex(func) |
| 120 | + vals = MOI.Utilities.eachscalar(func) |
| 121 | + dim = length(vals) |
| 122 | + side = isqrt(dim) |
| 123 | + k_re = 1 |
| 124 | + k_im = div(side * (side + 1), 2) + 1 |
| 125 | + l = 1 |
| 126 | + perm = zeros(Int, dim) |
| 127 | + for i in 1:side |
| 128 | + for j in 1:(i-1) |
| 129 | + perm[l] = k_re |
| 130 | + perm[l+1] = k_im |
| 131 | + k_re += 1 |
| 132 | + k_im += 1 |
| 133 | + l += 2 |
| 134 | + end |
| 135 | + perm[l] = k_re |
| 136 | + k_re += 1 |
| 137 | + l += 1 |
| 138 | + end |
| 139 | + return vals[perm] |
| 140 | +end |
| 141 | + |
| 142 | +function _complex_to_hermitian(func) |
| 143 | + vals = MOI.Utilities.eachscalar(func) |
| 144 | + dim = length(vals) |
| 145 | + side = isqrt(dim) |
| 146 | + k_re = 1 |
| 147 | + k_im = div(side * (side + 1), 2) + 1 |
| 148 | + l = 1 |
| 149 | + perm = zeros(Int, dim) |
| 150 | + for i in 1:side |
| 151 | + for j in 1:(i-1) |
| 152 | + perm[k_re] = l |
| 153 | + perm[k_im] = l + 1 |
| 154 | + k_re += 1 |
| 155 | + k_im += 1 |
| 156 | + l += 2 |
| 157 | + end |
| 158 | + perm[k_re] = l |
| 159 | + k_re += 1 |
| 160 | + l += 1 |
| 161 | + end |
| 162 | + return vals[perm] |
| 163 | +end |
| 164 | + |
| 165 | +# Map ConstraintFunction from Hermitian -> Complex |
| 166 | +function MOI.Bridges.map_function(::Type{<:HermitianComplexPSDConeBridge}, f) |
| 167 | + return _hermitian_to_complex(f) |
| 168 | +end |
| 169 | + |
| 170 | +# Used to map the ConstraintPrimal from Complex -> Hermitian |
| 171 | +function MOI.Bridges.inverse_map_function( |
| 172 | + ::Type{<:HermitianComplexPSDConeBridge}, |
| 173 | + f, |
| 174 | +) |
| 175 | + return _complex_to_hermitian(f) |
| 176 | +end |
| 177 | + |
| 178 | +# Used to map the ConstraintDual from Complex -> Hermitian |
| 179 | +function MOI.Bridges.adjoint_map_function( |
| 180 | + ::Type{<:HermitianComplexPSDConeBridge}, |
| 181 | + f, |
| 182 | +) |
| 183 | + return _complex_to_hermitian(f) |
| 184 | +end |
| 185 | + |
| 186 | +# Used to set ConstraintDualStart |
| 187 | +function MOI.Bridges.inverse_adjoint_map_function( |
| 188 | + ::Type{<:HermitianComplexPSDConeBridge}, |
| 189 | + f, |
| 190 | +) |
| 191 | + return _hermitian_to_complex(f) |
| 192 | +end |
0 commit comments