Fixing up nix deps

Author: hcallahan-lowrisc

flake.lock

@@ -5,22 +5,24 @@
   description = "Environment for developing and simulating the ibex core.";
 
   inputs = {
-    nixpkgs.url = "nixpkgs/nixos-24.05";
-    flake-utils.url = "github:numtide/flake-utils";
+
+    nixpkgs.follows = "lowrisc-nix/nixpkgs";
+    flake-utils.follows = "lowrisc-nix/flake-utils";
 
     poetry2nix = {
       url = "github:nix-community/poetry2nix";
       inputs.nixpkgs.follows = "nixpkgs";
       inputs.flake-utils.follows = "flake-utils";
     };
+
     mkshell-minimal.url = "github:viperML/mkshell-minimal";
 
     # The input 'lowrisc-nix' contains some common dependencies that can be used
     # by lowRISC projects. There is also an associated public binary cache.
     lowrisc-nix = {
+      # Checkout from when
+      # url = "github:lowrisc/lowrisc-nix?ref=d7e90e450bcfbed83b6b8a2458d29c0ddd7fe58d";
       url = "github:lowrisc/lowrisc-nix";
-      inputs.nixpkgs.follows = "nixpkgs";
-      inputs.flake-utils.follows = "flake-utils";
     };
 
     psgen = {

flake.nix

@@ -9,7 +9,7 @@
 }: let
   poetry2nix = inputs.poetry2nix.lib.mkPoetry2Nix {inherit pkgs;};
   ibexPoetryOverrides = import ./poetryOverrides.nix {inherit pkgs;};
-  lowriscPoetryOverrides = inputs.lowrisc-nix.lib.poetryOverrides {inherit pkgs;};
+  lowriscPoetryOverrides = import ./poetryOverridesLowriscNix.nix {inherit pkgs;};
 in
   poetry2nix.mkPoetryEnv {
     projectDir = ./.;

nix/env/default.nix

@@ -0,0 +1,87 @@
+# Copyright lowRISC Contributors.
+# Licensed under the MIT License, see LICENSE for details.
+# SPDX-License-Identifier: MIT
+{pkgs, ...}: let
+  # https://github.com/nix-community/poetry2nix/blob/master/docs/edgecases.md
+  # poetry2nix tries to build the python packages based on the information
+  # given in their own build description files (setup.py etc.)
+  # Sometimes, the inputs are incomplete. Add missing inputs here.
+  pypkgs-missing-build-requirements = {
+    # package: build-requirements #
+    attrs = ["hatchling" "hatch-fancy-pypi-readme" "hatch-vcs"];
+    beautifulsoup4 = ["hatchling"];
+    pyfinite = ["setuptools"];
+    zipfile2 = ["setuptools"];
+    okonomiyaki = ["setuptools"];
+    simplesat = ["setuptools"];
+    urllib3 = ["hatchling"];
+    fusesoc = ["setuptools" "setuptools-scm"];
+    chipwhisperer = ["setuptools"];
+    siphash = ["setuptools"];
+    tockloader = ["setuptools"];
+  };
+  buildreqs-overlay = (
+    final: prev:
+      builtins.mapAttrs (
+        package: build-requirements:
+          (builtins.getAttr package prev).overridePythonAttrs (old: {
+            buildInputs =
+              (old.buildInputs or [])
+              ++ (
+                builtins.map
+                (pkg: builtins.getAttr pkg final)
+                build-requirements
+              );
+          })
+      )
+      pypkgs-missing-build-requirements
+  );
+
+  # The following modules are very slow to build or are otherwise broken.
+  # For now, preferWheel to pull the binary dist.
+  preferwheel-overlay = final: prev: {
+    mypy = prev.mypy.override {
+      # Very slow build.
+      preferWheel = true;
+    };
+    libcst = prev.libcst.override {
+      preferWheel = true;
+      #  }).overridePythonAttrs ( old: {
+      #      # This fix is incomplete, and appears to be due to the issue here:
+      #      # https://github.com/nix-community/poetry2nix/issues/413
+      #      # https://github.com/nix-community/poetry2nix/issues/442
+      #      buildInputs = (old.buildInputs or []) ++ [
+      #        pkgs.rustc
+      #        pkgs.cargo
+      #        # pkgs.rustPlatform.cargoSetupHook
+      #        final.setuptools-rust
+      #      ];
+      #    });
+    };
+    # isort = prev.isort.override {
+    #   # Some problem building due to a malformed semantic version string.
+    #   preferWheel = true;
+    # };
+    # ninja = prev.ninja.override {
+    #   # Build error.
+    #   preferWheel = true;
+    # };
+    pyyaml = prev.pyyaml.override {
+      # Build error.
+      preferWheel = true;
+    };
+  };
+
+  # Nix wraps python programs which causes PATH to change. We want to keep
+  # PATH in case a program needs to invoke user-defined programs.
+  dontwrap-overlay = final: prev: {
+    fusesoc = prev.fusesoc.overridePythonAttrs {
+      dontWrapPythonPrograms = true;
+    };
+  };
+in
+  pkgs.lib.composeManyExtensions [
+    preferwheel-overlay
+    buildreqs-overlay
+    dontwrap-overlay
+  ]