Crosspost: heatmap axis tick labels are not well aligned

[ConnectedSystems]

Initially reported at YAXArrays.jl as I wasn't sure where the issue was coming from.

JuliaDataCubes/YAXArrays.jl#563

Cliffnotes:

With latest YAXArrays, GLMakie (and dependent DimensionalData version), the axis tick labels as string or symbols do not align. Numeric tick values work fine.

Downgrading to DimensionalData v0.28.1 resolves the issue.

Original post below

---

Having trouble with using the Makie plot extensions.
I am unsure if this is an issue with YAXArrays, Makie or something else? (DimensionalData perhaps?)

These figures were being created fine before, with each x and y name being correctly displayed.

Setup for minimum example:

using GLMakie
using YAXArrays

data = Matrix(
    [-0.00511588  -0.484493     0.465729
         -0.598729    -0.484493    -0.433482
          0.0877616    0.00859982   0.383126
          0.03808      0.14629      0.196582
         -0.17817     -0.484493     0.252583
          0.0431728   -0.431208     0.460954
         -0.0369392   -0.353446     0.277879
          0.107947    -1.25138e-5   0.459413
          0.211389     0.14629      0.390068
          0.402262     0.47797      0.213664
          0.0766013    0.188613     0.0751029]
)

props = Dict(
    "x" => "x",
    "y" => "y"
)

As Symbol:

xs = [Symbol("x$i") for i in 1:11]
ys = [Symbol("x$i") for i in 1:3]
axlist = Tuple(
    Dim{n}(v) for (n, v) in zip((:x, :y), (xs, ys))
)
d = YAXArray(
    axlist, data, props
)

heatmap(d)

As string:

xs = ["x$i" for i in 1:11]
ys = ["x$i" for i in 1:3]
axlist = Tuple(
    Dim{n}(v) for (n, v) in zip((:x, :y), (xs, ys))
)
d = YAXArray(
    axlist, data, props
)

heatmap(d)

As numeric:

xs = collect(1:11)
ys = collect(1:3)
axlist = Tuple(
    Dim{n}(v) for (n, v) in zip((:x, :y), (xs, ys))
)
d = YAXArray(
    axlist, data, props
)

heatmap(d)

[rafaqz]

Weird... they should be evenly spaced for a categorical lookup.

Can you paste what shows in the repl when you create the YAXArray d in the broken example?

[felixcremer]

I can replicate this with plain DimArrays and I expect #1012 to be the source of the change, because downgrading to 0.29.18 also shows the expected behaviour of evenly spaced ticks for categorical lookups.

[lazarusA]

anything to do with Ordered and Unordered lookups? specially in the axlist.

[felixcremer]

I think, that Order is a red herring, because changing the order of the dimensions via set doesn't change the plotting behaviour.
But the plotting behaviour changes on the length of the x dimension.
If this is only 4 elements the ticks are plotted evenly distributed.

[rafaqz]

@DylanMMarques any ideas?

[DylanMMarques]

Hi all,

The reason is how the lookup dimensions of symbols are being converted to numeric values here:

get_number_version(x::AbstractVector{<:AbstractString}) = sum.(Int, x) # Sum all chars
get_number_version(x::AbstractVector{<:Symbol}) = get_number_version(string.(x))

Ex:

xs = [Symbol("x$i") for i in 1:11]
get_number_version(xs)
11-element Vector{Int64}:
 169
 170
 171
 172
 173
 174
 175
 176
 177
 217
 218

In previous version 0.28, I think that it was converted into the positions range(1, step =1, length = length(x)). This had some contra-intuitive plotting behaviours for example when plotting:

lines(rand(X('a':'d')))
lines!(rand(X('b':'e')))

The issue was that the position 'a' and 'b' would be plotted in the same coordinate.

The current solution is not ideal but I am not sure what is the best way to convert to plotting coordinates in these cases. Any suggestions?

[ConnectedSystems]

Naively, my solution would be:

get_number_version(x::AbstractVector{<:AbstractChar}) = sum.(Int, x)  # Sum all chars
get_number_version(x::AbstractVector{<:AbstractString}) = collect(1:length(x))
get_number_version(x::AbstractVector{<:Symbol}) = get_number_version(string.(x))

To support both use cases more cleanly though, is there deeper plotting logic somewhere where all x-axis tick labels can be consolidated and made contiguous?

I guess this is delving into Makie territory though.

[DylanMMarques]

That solution would work for your case but would run into the issue that I mention on some cases. Ex:

xs = [Symbol("x$i") for i in 1:11]
lines(rand(X(xs))
lines!(rand(X(xs[2:end])))

I wasn't aware of Makie's CategoricalConversion and I think that CategoricalConversion could be used to solve this.

scatter(Categorical(["a", "b", "c", "d"]), Categorical([:a1, :c1, :b1, :d1]))
scatter!(Categorical(["a", "b", "c", "d"][2:end]), Categorical([:a1, :c1, :b1, :d1][2:end]))

For your case:

xs = [Symbol("x" * string(lpad(i, 2, "0"))) for i in 1:11] # Need the lpad for Makie to plot correctly
heatmap(Categorical(xs), Categorical(xs), rand(11,11))

A good think about this is that is also allows for the user to customise how the dimensions are handle. For example:

normal_order = Makie.CategoricalConversion(sortby=x -> parse(Int, string(x)[2:end]))
invert_order = Makie.CategoricalConversion(sortby=x -> -parse(Int, string(x)[2:end]))
heatmap(Categorical(xs), Categorical(xs), rand(11,11), axis=(dim1_conversion=normal_order, dim2_conversion=invert_order))

I haven't tested with DD, but it should not be too hard to implement. Most of it should be detecting if it is a categorical dimension and passing that lookup as Categorical.