Fix midpoint for tower rings

Add helper methods for the "midpoint" of a ring (which is the ring
where the midpoints of polynomials lie).

Author: d-torrance

M2/Macaulay2/m2/intervals.m2

@@ -123,16 +123,16 @@ isEmpty CCi := x -> isEmptyRRi realPart x or isEmptyRRi imaginaryPart x
 midpoint = method()
 midpoint Number := identity
 midpoint RRi := midpoint CCi := midpoint0
+
+midpoint Ring := R -> (
+    if instance(R, RealIntervalField) then RR_(precision R)
+    else if instance(R, ComplexIntervalField) then CC_(precision R)
+    else R)
+
 midpoint RingElement := f -> (
-    R := ring f;
-    kk := coefficientRing R;
-    S := R.cache#"midpoint ring" ??= (
-	if instance(kk, RealIntervalField)
-	then RR_(precision kk) monoid R
-	else if instance(kk, ComplexIntervalField)
-	then CC_(precision kk) monoid R
-	else R);
-    sum(listForm f, (m, c) -> midpoint c * product(#m, i -> S_i^(m#i))))
+    R := midpoint ring f;
+    if R === ring f then f
+    else sum(listForm f, (m, c) -> midpoint c * product(#m, i -> R_i^(m#i))))
 
 toExternalString RRi := x -> "interval" | toExternalString (left x, right x)
 toExternalString CCi := x -> "interval" | toExternalString (left realPart x+(left imaginaryPart x)*ii,right realPart x+(right imaginaryPart x)*ii)

M2/Macaulay2/m2/polyrings.m2

@@ -287,6 +287,11 @@ selectVariables(List,PolynomialRing) := (v,R) -> (
 antipode = method();
 antipode RingElement := (f) -> new ring f from rawAntipode raw f;
 
+midpoint PolynomialRing := R -> R.cache.midpoint ??= (
+    S := midpoint coefficientRing R;
+    if S === coefficientRing R then R
+    else S monoid R)
+
 -- Local Variables:
 -- compile-command: "make -C $M2BUILDDIR/Macaulay2/m2 "
 -- End:

M2/Macaulay2/packages/Macaulay2Doc/doc_intervals.m2

@@ -42,6 +42,9 @@ SeeAlso
     diameter
 ///
 
+-- helper methods not intended to be called by the user
+undocumented {(midpoint, Ring), (midpoint, PolynomialRing)}
+
 doc ///
 Key
      midpoint