[rtl] Annotate traces with expanded instruction information

The tracer usually only sees the instructions that reach the ID stage.
Since the Zcmp instructions are expanded in the IF stage, they will be
traced as their micro-ops. This adds information in the trace from which
expanded instruction those micro-ops come from.

Author: SamuelRiedel

rtl/ibex_top_tracing.sv

@@ -314,7 +314,8 @@ module ibex_top_tracing import ibex_pkg::*; #(
     .rvfi_mem_rmask,
     .rvfi_mem_wmask,
     .rvfi_mem_rdata,
-    .rvfi_mem_wdata
+    .rvfi_mem_wdata,
+    .rvfi_ext_expanded_insn
   );
 
 endmodule

rtl/ibex_tracer.sv

@@ -65,7 +65,8 @@ module ibex_tracer (
   input logic [ 3:0] rvfi_mem_rmask,
   input logic [ 3:0] rvfi_mem_wmask,
   input logic [31:0] rvfi_mem_rdata,
-  input logic [31:0] rvfi_mem_wdata
+  input logic [31:0] rvfi_mem_wdata,
+  input logic [15:0] rvfi_ext_expanded_insn
 );
 
   // These signals are part of RVFI, but not used in this module currently.
@@ -143,6 +144,9 @@ module ibex_tracer (
         $fwrite(fh, " load:0x%08x", rvfi_mem_rdata);
       end
     end
+    if (rvfi_ext_expanded_insn != 16'b0) begin
+      $fwrite(fh, " expand_insn: (0x%04x %s)", rvfi_ext_expanded_insn, decode_expanded_insn());
+    end
 
     $fwrite(fh, "\n");
   endfunction
@@ -157,6 +161,32 @@ module ibex_tracer (
     end
   endfunction
 
+  // Format register address with "x" prefix, left-aligned to a fixed width of 3 characters.
+  function automatic string reg_addr_to_abi_str(input logic [4:0] addr);
+    case (addr)
+      // Hard-wired Zero Register
+      5'd0: return "zero";
+      // Return Address and Pointers
+      5'd1: return "ra";   // Return Address
+      5'd2: return "sp";   // Stack Pointer
+      5'd3: return "gp";   // Global Pointer
+      5'd4: return "tp";   // Thread Pointer
+      // Temporary Registers
+      5'd5, 5'd6, 5'd7: return $sformatf("t%0d", addr - 5);
+      // Saved Registers
+      5'd8, 5'd9: return $sformatf("s%0d", addr - 8);
+      // Function Arguments / Return Values
+      5'd10, 5'd11, 5'd12, 5'd13,
+      5'd14, 5'd15, 5'd16, 5'd17: return $sformatf("a%0d", addr - 10);
+      // Saved Registers
+      5'd18, 5'd19, 5'd20, 5'd21, 5'd22,
+      5'd23, 5'd24, 5'd25, 5'd26, 5'd27: return $sformatf("s%0d", addr - 16);
+      // Temporary Registers
+      5'd28, 5'd29, 5'd30, 5'd31: return $sformatf("t%0d", addr - 25);
+      default: return $sformatf("x%0d", addr);
+    endcase
+  endfunction
+
   // Get a CSR name for a CSR address.
   function automatic string get_csr_name(input logic [11:0] csr_addr);
     unique case (csr_addr)
@@ -664,6 +694,55 @@ module ibex_tracer (
     decoded_str = $sformatf("%s\tx%0d,%0d(x%0d)", mnemonic, rvfi_rd_addr, imm, rvfi_rs1_addr);
   endfunction
 
+  function automatic string cm_reg_to_str(input logic [2:0] addr);
+    logic [4:0] xreg = {addr[2:1] > 0, addr[2:1]==0, addr[2:0]};
+    return reg_addr_to_abi_str(xreg);
+  endfunction
+
+  function automatic string decode_Zcmp_cmmv_insn(input string mnemonic);
+    return $sformatf("%s\t%0s,%0s", mnemonic, cm_reg_to_str(rvfi_ext_expanded_insn[9:7]),
+                     cm_reg_to_str(rvfi_ext_expanded_insn[4:2]));
+  endfunction
+
+  function automatic string decode_Zcmp_cmpp_insn(input string mnemonic);
+    logic [3:0] rlist;
+    logic [1:0] spimm;
+    string rlist_str;
+    int base;
+    int spimm_val;
+    rlist = rvfi_ext_expanded_insn[7:4];
+    spimm = rvfi_ext_expanded_insn[3:2];
+    // Decode rlist to string
+    if (rlist < 4) begin
+      rlist_str = $sformatf("{INVALID (%0d)}", rlist);
+    end else begin
+      case(rlist)
+        4:  rlist_str = "{ra}";
+        5:  rlist_str = "{ra, s0}";
+        15: rlist_str = "{ra, s0-s11}"; // The special case for s10/s11
+        // The default case handles the general pattern for rlist 6 through 14
+        default: rlist_str = $sformatf("{ra, s0-s%0d}", rlist - 5);
+      endcase
+    end
+    // Decode spimm
+    base = (rlist == 15) ? 64 : (32'(rlist) >> 2) * 16;
+    spimm_val = base + (spimm * 16);
+    spimm_val = mnemonic == "cm.push" ? -spimm_val : spimm_val;
+    return $sformatf("%s\t%s,%0d", mnemonic, rlist_str, spimm_val);
+  endfunction
+
+  function automatic string decode_expanded_insn();
+    unique casez (rvfi_ext_expanded_insn)
+      INSN_CMPUSH:    return decode_Zcmp_cmpp_insn("cm.push");
+      INSN_CMPOP:     return decode_Zcmp_cmpp_insn("cm.pop");
+      INSN_CMPOPRETZ: return decode_Zcmp_cmpp_insn("cm.popretz");
+      INSN_CMPOPRET:  return decode_Zcmp_cmpp_insn("cm.popret");
+      INSN_CMMVSA01:  return decode_Zcmp_cmmv_insn("cm.mvsa01");
+      INSN_CMMVA01S:  return decode_Zcmp_cmmv_insn("cm.mva01s");
+      default:        return "Decoding error";
+    endcase
+  endfunction
+
   function automatic void decode_load_insn();
     string      mnemonic;
 
@@ -879,6 +958,9 @@ module ibex_tracer (
           INSN_CSLLI:      decode_ci_cslli_insn("c.slli");
           INSN_CLWSP:      decode_compressed_load_insn("c.lwsp");
           INSN_SWSP:       decode_compressed_store_insn("c.swsp");
+          // Zc extension C2: We should never see those on the rvfi_insn interface since they must
+          // get expanded into other instructions. They will be annotated through the
+          // `decode_expanded_insn` function instead and the `rvfi_ext_expanded_insn` signal.
           default:         decode_mnemonic("INVALID");
         endcase
       end

rtl/ibex_tracer_pkg.sv

@@ -344,5 +344,12 @@ package ibex_tracer_pkg;
   parameter logic [15:0] INSN_CEBREAK    = { 3'b100, 1'b1,        5'h0,  5'h0,       {OPCODE_C2} };
   parameter logic [15:0] INSN_CJR        = { 3'b100, 1'b0,        5'h0,  5'h0,       {OPCODE_C2} };
   parameter logic [15:0] INSN_CJALR      = { 3'b100, 1'b1,        5'h?,  5'h0,       {OPCODE_C2} };
+  // Zc extension Cc
+  parameter logic [15:0] INSN_CMPUSH     = { 3'b101, 3'b110, 2'b00, 4'h?, 2'b?,      {OPCODE_C2} };
+  parameter logic [15:0] INSN_CMPOP      = { 3'b101, 3'b110, 2'b10, 4'h?, 2'b?,      {OPCODE_C2} };
+  parameter logic [15:0] INSN_CMPOPRETZ  = { 3'b101, 3'b111, 2'b00, 4'h?, 2'b?,      {OPCODE_C2} };
+  parameter logic [15:0] INSN_CMPOPRET   = { 3'b101, 3'b111, 2'b10, 4'h?, 2'b?,      {OPCODE_C2} };
+  parameter logic [15:0] INSN_CMMVSA01   = { 3'b101, 3'b011, 3'h?, 2'b01, 3'h?,      {OPCODE_C2} };
+  parameter logic [15:0] INSN_CMMVA01S   = { 3'b101, 3'b011, 3'h?, 2'b11, 3'h?,      {OPCODE_C2} };
 
 endpackage